作りながら学ぶArduino+=電子工作入門

　センサが温度を測ったりA-D変換するのにはある程度の時間がかかります。通常は、変換完了を割り込み信号で用意し、DataReadyなどの信号をTrueにして外部に知らせます。そのためには、データ転送以外に信号線が必要です。I2Cでは、変換が完了していないことを知らせる機能があります。I2CのクロックSCL信号をLOWのままスレーブ・デバイスが維持する＝クロック・ストレッチによりマスタを待たせます。複数のスレーブ・デバイスがつながっていても機能します。

　ここでは、クロック・ストレッチを利用する/しないを明示して使える温湿度センサSHT31のタイミングを観測します。ラズパイで利用した記事、Micro:bitで使用した記事、Arduino UNOで使用した記事も参照ください。

●SHT31のおもなスペック

　電源電圧は3.3V、5Vのどちらでも動きます。I2Cのデータ転送速度は最大1MHzです。測定温度範囲は-40～＋125℃（確度±0.2℃）、分解能0.015℃、測定相対湿度範囲は0～100%（0~90℃時）、分解能0.01%です。

　I2Cのデータ転送速度の多くは0～400kHzが多いです。最初に、デフォルトの100kHz、最大1MHzまで転送速度を変化させて、波形を観測します。

●100kHzのスケッチ

　100kHzはデフォルトなので、データ転送速度は記述していません。SHT31は、単発測定コマンド0x2400を実行しています。

#include <Wire.h>
unsigned char SHT31_address = 0x44;
int Stemp;unsigned int SRH;
float temp;float RH;
byte readbuffer[6];

void setup() {
    Wire.begin();
    Wire.beginTransmission(SHT31_address);
        Wire.write(0x30);Wire.write(0xa2); //reset
    Wire.endTransmission(); 
    Serial.begin(9600);
    delay(10);
    Serial.println("start ");
}

void loop() {
    Wire.beginTransmission(SHT31_address);
        Wire.write(0x24);Wire.write(0x00);
    Wire.endTransmission(); 
    Wire.requestFrom(SHT31_address, 6);
    readbuffer[0] = Wire.read();
    readbuffer[1] = Wire.read();
    readbuffer[2] = Wire.read(); // CRC
    readbuffer[3] = Wire.read();
    readbuffer[4] = Wire.read();
    readbuffer[5] = Wire.read(); // CRC
    if (readbuffer[2] == crc8(readbuffer)) {
        Stemp = readbuffer[0] << 8 | readbuffer[1];
        temp = -45 + Stemp * 175.0 / 65535.0;
    }
    if (readbuffer[5] == crc8(readbuffer+3)) {
        SRH = readbuffer[3] << 8 | readbuffer[4];
        RH = 100.0 * SRH / 65535.0;
    }
    Serial.println(" temp= "+String(temp,1)+"'C");
    Serial.println(" RH%= "+String(RH,0));
    delay(30);
}

unsigned char table[256] ={
    0, 94, 188, 226, 97, 63, 221, 131, 194, 156, 126, 32, 163, 253, 31, 65,157, 195, 33, 127, 252, 162, 64, 30, 95, 1, 227, 189, 62, 96, 130, 220,35, 125, 159,193, 66, 28, 254, 160, 225, 191, 93, 3, 128, 222, 60, 98, 190, 224, 2, 92, 223, 129, 99, 61, 124, 34, 192, 158, 29, 67, 161, 255,70, 24, 250, 164, 39, 121, 155, 197, 132, 218, 56, 102, 229, 187, 89, 7, 219, 133, 103, 57, 186, 228, 6, 88, 25, 71, 165, 251, 120, 38, 196, 154, 101, 59, 217, 135, 4, 90, 184, 230, 167, 249, 27, 69, 198, 152, 122, 36,248, 166, 68, 26, 153, 199, 37, 123, 58, 100, 134, 216, 91, 5, 231, 185,140, 210, 48, 110, 237, 179, 81, 15, 78, 16, 242, 172, 47, 113, 147, 205,17, 79, 173, 243, 112, 46, 204, 146, 211, 141, 111, 49, 178, 236, 14, 80,175, 241, 19, 77, 206, 144, 114, 44, 109, 51, 209, 143, 12, 82, 176, 238, 50, 108, 142, 208, 83, 13, 239, 177, 240, 174, 76, 18, 145, 207, 45, 115,202, 148, 118, 40, 171, 245, 23, 73, 8, 86, 180, 234, 105, 55, 213, 139,87, 9, 235, 181, 54, 104, 138, 212, 149, 203, 41, 119, 244, 170, 72, 22,233, 183, 85, 11, 136, 214, 52, 106, 43, 117, 151, 201, 74, 20, 246, 168,116, 42, 200, 150, 21, 75, 169, 247, 182, 232, 10, 84, 215, 137, 107, 53
};
    unsigned char crc8(const unsigned char * data){
    unsigned char crc = 0xff;
    crc = table[reflect(data[0]) ^ crc];
    crc = table[reflect(data[1]) ^ crc];
    return reflect(crc);
}

unsigned char reflect(unsigned char c){
    unsigned char r=0;
    for (int i=0;i<8;i++){
        if (c&(1<<i)){
            r=r|(1<<(7-i));
        }
    }
    return r;
}

　このときの波形です。クロックは約100kHzです。

　Wire.begin();のあとに、Wire.setClock(4000000L);を追加しました。その波形です。約310kHzです。データの後半に送られる湿度データが異常ですね。

　Wire.setClock(10000000L);に変更しました。I2Cは5V時、HIGHは3.5V以上なので、電圧レベルの問題ではないように見えます。

　波形がなまっているので、プルアップ抵抗値8.2kΩを820Ωに変更しましたが、1MHzのデータ転送はできないようです。ATMega328のI2CインターフェースであるTWIの機能の限界かどうかは不明です。

●クロック・ストレッチを要求する単発測定コマンド

　データ転送速度をデフォルトの100kHzに戻しました。SHT31の単発測定コマンドのなかで、クロック・ストレッチを要求する設定パラメータは0x2c06から0x2c10です。Wire.write(0x24);Wire.write(0x00);をWire.write(0x2c);Wire.write(0x10);に変更した波形です。Wireライブラリのコマンドで、クロック・ストレッチを指示してはいません。

　このスケッチのままでデータ転送速度を400kHzに変更しました。すると、湿度データも正常になっています。

　SHT31にかぎらず、デバイスはON/OFFが多いと、自己発熱します。その結果、測定データの確度が悪くなる傾向があります。SHT31にも連続測定モードがあります。電池駆動でなければ気になりませんが、単発測定コマンドのほうが、必要なときにだけ測定するので、消費電力を下げられます。また、クロック・ストレッチだと、確実に変換が終わった後にデータを受け取れます。

　スケッチにはソフトウェア・リセットは記入していますが、測定モードが切り替わらないことがあります。そのときは電源を10秒ほど切ってから再度入れなおすと、新しい測定モードになりました。

（※）クロック・ストレッチがどのデバイスでも本記事のように働くかどうかは不明です。