CO2センサを使う③AdafruitのSCD-30ボードをArduino Nano RP2040 ConnectにつないでBLEペリフェラルに（2）

　前回、CO2のデータを文字で送りました。

　ここでは、実数で送るように変更します。また、Descriptorの記述を追加します。

●スケッチ

　DescriptorのUUIDを128ではなく16ビットにすると、うまく送れるようになりました（末尾の参考URLを参照）。


#include <ArduinoBLE.h>

#define SCD30_SERVICE_UUID   "F000AA30-0451-4000-B000-000000000000"
// BLE Service
BLEService Sensor_SCD30_Service(SCD30_SERVICE_UUID);

#define SCD30_Characteristic_UUID    "F000AA31-0451-4000-B000-000000000000"
// BLE  Characteristic
BLEFloatCharacteristic  SCD30_CO2_Characteristic(SCD30_Characteristic_UUID, BLERead | BLENotify);

#define SCD30_Descriptor_UUID    "2901"
// BLE  Descriptor
BLEDescriptor   SCD30_CO2_Descriptor(SCD30_Descriptor_UUID, "CO2;ppm IEEE-754 format");

#include <Adafruit_SCD30.h>
Adafruit_SCD30  scd30;
float CO2 = 0;
 
void readSCD30() {
  if (scd30.dataReady()){
    if (!scd30.read()){ Serial.println("Error reading sensor data"); return; }
      CO2 = scd30.CO2;
  }
}

#define localNAME  "RP2060_SCD30_float"
#define DeviceNAME "RP2060_CO2_BLE"
 
float oldValue = 0;  // last value 
float previousMillis = 0;  // last time value was checked, in ms
 
void setup() {
  Serial.begin(9600);    // initialize serial communication
  while (!Serial);
 
  // begin initialization
  if (!BLE.begin()) {
    Serial.println("starting BLE failed!");
    while (1);
  }
 
  if (!scd30.begin()) {
    Serial.println("Failed to find SCD30 chip");
    while (1) { delay(10); }
  }
  
  BLE.setLocalName(localNAME);
  BLE.setDeviceName(DeviceNAME);

  // add the service UUID
  BLE.setAdvertisedService(Sensor_SCD30_Service);



  // add characteristic
  Sensor_SCD30_Service.addCharacteristic(SCD30_CO2_Characteristic);

  // add descriptor
  SCD30_CO2_Characteristic.addDescriptor(SCD30_CO2_Descriptor);
  
  // Add service
  BLE.addService(Sensor_SCD30_Service);
 
  // set initial value for this characteristic
  SCD30_CO2_Characteristic.writeValue(oldValue);

  
  // start advertising
  BLE.advertise();
  Serial.println("Bluetooth device active, waiting for connections...");
}
 
void loop() {
  // wait for a BLE central
  BLEDevice central = BLE.central();
 
  // if a central is connected to the peripheral:
  if (central) {
    delay(100);
    Serial.print("Connected to central: ");
    // print the central's BT address:
    Serial.println(central.address());
 
    // check  every 200ms. while the central is connected:
    while (central.connected()) {
      long currentMillis = millis();
      // if 200ms have passed, check value:
      if (currentMillis - previousMillis >= 200) {
        previousMillis = currentMillis;
        updateValue();
        delay(1000);
      }
    }
    // when the central disconnects
    Serial.print("Disconnected from central: ");
    Serial.println(central.address());
  }
}

void updateValue() {
  readSCD30();

  // if value has changed
  if (CO2 != oldValue) {

    Serial.print(String(CO2,2));
    Serial.println("ppm");
    
    // update  characteristic
    SCD30_CO2_Characteristic.writeValue(CO2);
    oldValue = CO2; // save the level for next comparison
  }
}

　RSL10のモニタで観測しました。追加したDescriptorは、赤枠のように表示されています。

　実数は、IEEE-754フォーマットで、単精度浮動小数点数の形式：binary32です。4バイトのバイト列でデータが送られます。

　こちらのサイトで変換できます。今回は、リトル・エンディアンなので、逆順Swap endiannessにチェックを入れます。

（※）参考　フォーラム Sending float over BLE